배포할 때마다 끊기던 서비스를 무중단으로: Jenkins Rolling Deployment에서 내린 네 가지 결정

stage('App. SSH Deploy') {
  when {
    expression { env.ONLY_BUILD != 'true' }
  }
  steps([$class: 'BapSshPromotionPublisherPlugin']) {
    script {
      targets = env.SSH_SERVERS.split(',')
      targets.each { server ->
        echo "TARGET SSH SERVER : ${server}"
        sshPublisher(
          continueOnError: false, failOnError: true,
          publishers: [
            sshPublisherDesc(
              configName: server,
              verbose: true,
              transfers: [
                sshTransfer(sourceFiles: env.SSH_SOURCE_FILES,
                  removePrefix: env.SSH_REMOVE_REFIX,
                  remoteDirectory: env.SSH_REMOTE_DIRECTORY,
                  execCommand: env.SSH_EXEC_COMMAND)
              ]
            )
          ]
        )
      }
    }
  }
}

parameters {
  // 기존 파라미터들...
  choice(name: 'INPUT_APPROVAL_MODE',
    choices: ['First server only', 'All servers', 'Verification Pass'],
    description: ''
  )
}

environment {
  // 기존 환경변수들...
  INPUT_APPROVAL_MODE = "${params.INPUT_APPROVAL_MODE}"
  LB_DEREGISTER_SCRIPT = "${env.LB_DEREGISTER_SCRIPT ?: 'lb_deregister.sh'}"
  LB_REGISTER_SCRIPT = "${env.LB_REGISTER_SCRIPT ?: 'lb_register.sh'}"
}

stage('App. Rolling Deploy') {
  when {
    expression { env.ONLY_BUILD != 'true' }
  }
  steps {
    script {
      def servers = env.SSH_SERVERS.split(',')
      def serverCount = servers.size()

      echo "Starting Rolling Deployment to ${serverCount} servers..."
      echo "Input Approval Mode: ${env.INPUT_APPROVAL_MODE}"

      servers.eachWithIndex { server, index ->
        def currentServerIndex = index + 1
        echo "=========================================="
        echo "배포 시작 ${currentServerIndex}/${serverCount}: ${server}"
        echo "=========================================="

        try {
          // 1. 배포 전에 LB에서 뺀다. 이 서버로는 새 요청이 오지 않는다
          echo "[Step 1] 로드 밸런서에서 ${server} 서버 등록 해제"
          executeLBScript(server, env.LB_DEREGISTER_SCRIPT, "deregister")

          // 2. JAR 배포 및 재시작. 기존 SSH Deploy와 같은 동작
          echo "[Step 2] ${server} 서버에 애플리케이션 배포 시작"
          deployToServer(server)

          // 3. 승인 모드에 따라 여기서 멈춘다. 서버는 아직 LB 밖이다
          if (shouldRequireInput(currentServerIndex, env.INPUT_APPROVAL_MODE)) {
            echo "[Step 3] ${server} 서버 배포 정상여부 확인 및 승인 대기"
            def approvalMessage = """
            🔄 배포 완료 진행률 ${currentServerIndex}/${serverCount} (${server})

            애플리케이션이 올바르게 작동하는지 확인하세요:
            • 애플리케이션 로그 확인
            • 서비스 상태 확인
            • 중요 기능 테스트

            'Proceed'을 클릭하여 서버를 로드 밸런서에 다시 등록하고 다음 서버로 계속 진행합니다.
            """

            input(
              message: approvalMessage,
              ok: 'Proceed',
              submitterParameter: 'APPROVER'
            )

            // echo "Deployment verification approved by: ${env.APPROVER}"
            echo "승인자: ${currentBuild.getBuildCauses('hudson.model.Cause$UserIdCause')[0]?.userId ?: 'Unknown'}"
          } else {
            echo "[Step 3] ${server} 서버 승인 건너뛰기 (mode: ${env.INPUT_APPROVAL_MODE})"
          }

          // 4. 검증이 끝난 뒤에야 LB에 되돌린다
          echo "[Step 4] ${server} 서버 로드밸런서에 다시 등록"
          executeLBScript(server, env.LB_REGISTER_SCRIPT, "register")

          echo "Server ${currentServerIndex}/${serverCount} (${server}) deployment completed successfully!"

        } catch (Exception e) {
          echo "❌ ${server} 서버에 배포하는 동안 오류가 발생했습니다. (${e.getMessage()})"

          try {
            // 실패한 서버를 LB 밖에 남겨 두지 않는다. Abort도 여기로 들어온다
            echo "🔄 ${server} 서버 로드밸런서에 다시 등록"
            executeLBScript(server, env.LB_REGISTER_SCRIPT, "register")
          } catch (Exception rollbackError) {
            echo "❌ Rollback failed: ${rollbackError.getMessage()}"
          }

          error "${server} 서버 배포 실패"
        }
      }

      echo "🎉 모든 서버에 대한 롤링 배포가 성공적으로 완료되었습니다."
    }
  }
}

def shouldRequireInput(serverIndex, inputMode) {
  switch(inputMode) {
    case 'First server only':
      return serverIndex == 1
    case 'All servers':
      return true
    case 'Verification Pass':
      return false
    default:
      return false
  }
}

def executeLBScript(server, script, action) {
  sshPublisher(
    continueOnError: false, failOnError: true,
    publishers: [
      sshPublisherDesc(
        configName: server,
        verbose: true,
        transfers: [
          sshTransfer(execCommand: "${script} ${server} ${action}")
        ]
      )
    ]
  )
}

def deployToServer(server) {
  sshPublisher(
    continueOnError: false, failOnError: true,
    publishers: [
      sshPublisherDesc(
        configName: server,
        verbose: true,
        transfers: [
          sshTransfer(
            sourceFiles: env.SSH_SOURCE_FILES,
            removePrefix: env.SSH_REMOVE_REFIX,
            remoteDirectory: env.SSH_REMOTE_DIRECTORY,
            execCommand: env.SSH_EXEC_COMMAND
          )
        ]
      )
    ]
  )
}

#!/bin/bash
# lb_deregister.sh
SERVER_NAME=$1
ACTION=$2
echo "Deregistering server $SERVER_NAME from Load Balancer..."
# AWS ALB, NGINX Upstream, HAProxy 등 실제 LB API 호출

#!/bin/bash
# lb_register.sh
SERVER_NAME=$1
ACTION=$2
echo "Registering server $SERVER_NAME to Load Balancer..."
# AWS ALB, NGINX Upstream, HAProxy 등 실제 LB API 호출

# 승인 절차 없이 자동 배포
Server 1: LB 해제 → 배포 → LB 등록
Server 2: LB 해제 → 배포 → LB 등록
Server 3: LB 해제 → 배포 → LB 등록

# 첫 번째 서버만 승인 절차 적용
Server 1: LB 해제 → 배포 → [승인 대기] → LB 등록
Server 2: LB 해제 → 배포 → LB 등록
Server 3: LB 해제 → 배포 → LB 등록

# 모든 서버에 승인 절차 적용
Server 1: LB 해제 → 배포 → [승인 대기] → LB 등록
Server 2: LB 해제 → 배포 → [승인 대기] → LB 등록
Server 3: LB 해제 → 배포 → [승인 대기] → LB 등록